|
|
一个使用asp和mdb的站点，某个mdb中使用了链接表，链接到当前目录的另一个mdb中的表，这样可以达到数据共享。
faq-it.org/delphi_win_sdk/问题来了，当将网站发布到网站的时候，因为网上空间路径和我本机不同，所以链接表失败，网页当然也不能打开。
我觉得解决办法有：
一种，在本机上创建与网上空间完全相同的目录结构。但这很麻烦，特别是经常要换网站的话。
一种，如何让链接表使用相对路径，就是链接到当前目录下的那个mdb文件？（对了，access很弱智，链接表记录的是绝对路径）。
还一种，如何通过编程（asp 或者本地vba）来实现对链接表的链接的修改？（又对了，access还是弱智，更新链接表我只能使用手工更新，一定要找到那个路径下的mdb才行！可本地路径和网上不一样呀）
谁能告诉我如何实现上面的后两种方法？
---------------------------------------------------------------
以下是我自己在用的adox代码，只为了证明我说的access有此功能(说句不好听的:这关access p事啊？这是ado模型该解决的问题。而且你也提错地方了，提到asp那一块更合适)，做access编程的都应该看得懂，如果你看不懂我也只能说遗憾了。
Public Function NewLinkedExternalTableMdb()
Dim strTargetDB() As String
Dim strProviderString() As String
Dim strSourceTbl() As String
Dim strLinkTblName() As String
Dim catDB As ADOX.Catalog
Dim tblLink As ADOX.Table
Dim tmpLink As ADOX.Table
Dim i As Integer
Dim j As Integer
Set catDB = New ADOX.Catalog
catDB.ActiveConnection = CurrentProject.Connection
i = catDB.Tables.Count
ReDim strTargetDB(i)
ReDim strProviderString(i)
ReDim strSourceTbl(i)
ReDim strLinkTblName(i)
i = 1
For Each tmpLink In catDB.Tables
If tmpLink.Properties("Jet OLEDB:Create Link") Then
If Trim(tmpLink.Properties("Jet OLEDB:Remote Table Name")) <> "" Then
strLinkTblName(i) = tmpLink.Name
strTargetDB(i) = tmpLink.Properties("Jet OLEDB:Link Datasource")
strProviderString(i) = tmpLink.Properties("Jet OLEDB:Link Provider String")
strSourceTbl(i) = tmpLink.Properties("Jet OLEDB:Remote Table Name")
Do While InStr(1, strTargetDB(i), "/") <> 0
strTargetDB(i) = Mid(strTargetDB(i), InStr(1, strTargetDB(i), "/") + 1, Len(strTargetDB(i)))
Loop
strTargetDB(i) = CurrentProject.Path & "/" & strTargetDB(i)
i = i + 1
End If
End If
Next
j = i - 1
For i = 1 To j
catDB.Tables.Delete strLinkTblName(i)
Set tblLink = New ADOX.Table
With tblLink
.Name = strLinkTblName(i)
Set .ParentCatalog = catDB
.Properties("Jet OLEDB:Create Link") = True
.Properties("Jet OLEDB:Link Datasource") = strTargetDB(i)
.Properties("Jet OLEDB:Link Provider String") = strProviderString(i)
.Properties("Jet OLEDB:Remote Table Name") = strSourceTbl(i)
End With
catDB.Tables.Append tblLink
Set tblLink = Nothing
Next
Set catDB = Nothing
End Function
|
|
发表于 2006-10-13 00:00:00
